fplot_scatter_plot_data.f90

! fplot_scatter_plot_data.f90
 
submodule(fplot_core) fplot_scatter_plot_data
contains
! ------------------------------------------------------------------------------
    module function spd_get_cmd(this) result(x)
        ! Arguments
        class(scatter_plot_data), intent(in) :: this
        character(len = :), allocatable :: x
 
        ! Local Variables
        type(string_builder) :: str
        integer(int32) :: n
        type(color) :: clr
 
        ! Initialization
        call str%initialize()
 
        ! Title
        n = len_trim(this%get_name())
        if (n > 0) then
            call str%append(' "-" title "')
            call str%append(this%get_name())
            call str%append('"')
        else
            call str%append(' "-" notitle')
        end if
 
        ! Lines, points, or filled
        if (this%get_fill_curve()) then
            call str%append(" with filledcurves")
        else
            if (this%get_draw_line() .and. this%get_draw_markers()) then
                call str%append(" with linespoints")
            else if (.not.this%get_draw_line() .and. this%get_draw_markers()) then
                call str%append(" with points")
            else
                call str%append(" with lines")
            end if
        end if
 
        ! Line Width
        call str%append(" lw ")
        call str%append(to_string(this%get_line_width()))
 
        ! Line Color
        if (this%get_use_data_dependent_colors()) then
            ! http://www.gnuplotting.org/using-a-palette-as-line-color/
            call str%append(" lc palette")
        else
            clr = this%get_line_color()
            call str%append(' lc rgb "#')
            call str%append(clr%to_hex_string())
            call str%append('"')
        end if
 
        ! Define other properties specific to the lines and points
        if (this%get_draw_line()) then
            call str%append(" lt ")
            call str%append(to_string(this%get_line_style()))
            if (this%get_line_style() /= line_solid) then
                call str%append(" dashtype ")
                call str%append(to_string(this%get_line_style()))
            end if
        end if
        if (this%get_draw_markers()) then
            call str%append(" pi ")
            call str%append(to_string(this%get_marker_frequency()))
            call str%append(" pt ")
            call str%append(to_string(this%get_marker_style()))
            call str%append(" ps ")
            if (this%get_use_variable_size_points()) then
                call str%append("variable")
            else
                call str%append(to_string(this%get_marker_scaling()))
            end if
        end if
 
        ! Define the axes structure
        call str%append(" ")
        call str%append(this%get_axes_string())
 
        ! End
        x = char(str%to_string())
    end function
 
! ------------------------------------------------------------------------------
    pure module function spd_get_line_width(this) result(x)
        class(scatter_plot_data), intent(in) :: this
        real(real32) :: x
        x = this%m_lineWidth
    end function
 
! --------------------
    module subroutine spd_set_line_width(this, x)
        class(scatter_plot_data), intent(inout) :: this
        real(real32), intent(in) :: x
        this%m_lineWidth = x
    end subroutine
 
! ------------------------------------------------------------------------------
    pure module function spd_get_line_style(this) result(x)
        class(scatter_plot_data), intent(in) :: this
        integer(int32) :: x
        x = this%m_lineStyle
    end function
 
! --------------------
    module subroutine spd_set_line_style(this, x)
        class(scatter_plot_data), intent(inout) :: this
        integer(int32), intent(in) :: x
        if (x == line_dashed .or. &
            x == line_dash_dotted .or. &
            x == line_dash_dot_dot .or. &
            x == line_dotted .or. &
            x == line_solid) then
            ! Only reset the line style if it is a valid type.
            this%m_lineStyle = x
        end if
    end subroutine
 
! ------------------------------------------------------------------------------
    pure module function spd_get_draw_line(this) result(x)
        class(scatter_plot_data), intent(in) :: this
        logical :: x
        x = this%m_drawLine
    end function
 
! --------------------
    module subroutine spd_set_draw_line(this, x)
        class(scatter_plot_data), intent(inout) :: this
        logical, intent(in) :: x
        this%m_drawLine = x
    end subroutine
 
! ------------------------------------------------------------------------------
    pure module function spd_get_draw_markers(this) result(x)
        class(scatter_plot_data), intent(in) :: this
        logical :: x
        x = this%m_drawMarkers
    end function
 
! --------------------
    module subroutine spd_set_draw_markers(this, x)
        class(scatter_plot_data), intent(inout) :: this
        logical, intent(in) :: x
        this%m_drawMarkers = x
    end subroutine
 
! ------------------------------------------------------------------------------
    pure module function spd_get_marker_style(this) result(x)
        class(scatter_plot_data), intent(in) :: this
        integer(int32) :: x
        x = this%m_markerType
    end function
 
! --------------------
    module subroutine spd_set_marker_style(this, x)
        class(scatter_plot_data), intent(inout) :: this
        integer(int32), intent(in) :: x
        if (x == marker_asterisk .or. &
            x == marker_empty_circle .or. &
            x == marker_empty_nabla .or. &
            x == marker_empty_rhombus .or. &
            x == marker_empty_square .or. &
            x == marker_empty_triangle .or. &
            x == marker_filled_circle .or. &
            x == marker_filled_nabla .or. &
            x == marker_filled_rhombus .or. &
            x == marker_filled_square .or. &
            x == marker_filled_triangle .or. &
            x == marker_plus .or. &
            x == marker_x) then
 
            ! Only alter the value if the marker is a known type
            this%m_markerType = x
        end if
    end subroutine
 
! ------------------------------------------------------------------------------
    pure module function spd_get_marker_scaling(this) result(x)
        class(scatter_plot_data), intent(in) :: this
        real(real32) :: x
        x = this%m_markerSize
    end function
 
! --------------------
    module subroutine spd_set_marker_scaling(this, x)
        class(scatter_plot_data), intent(inout) :: this
        real(real32), intent(in) :: x
        this%m_markerSize = x
    end subroutine
 
! ------------------------------------------------------------------------------
    pure module function spd_get_marker_frequency(this) result(x)
        class(scatter_plot_data), intent(in) :: this
        integer(int32) :: x
        x = this%m_markerFrequency
    end function
 
! --------------------
    module subroutine spd_set_marker_frequency(this, x)
        class(scatter_plot_data), intent(inout) :: this
        integer(int32), intent(in) :: x
        this%m_markerFrequency = x
    end subroutine
 
! ------------------------------------------------------------------------------
    pure module function spd_get_simplify_data(this) result(x)
        class(scatter_plot_data), intent(in) :: this
        logical :: x
        x = this%m_simplifyData
    end function
 
! --------------------
    module subroutine spd_set_simplify_data(this, x)
        class(scatter_plot_data), intent(inout) :: this
        logical, intent(in) :: x
        this%m_simplifyData = x
    end subroutine
 
! ------------------------------------------------------------------------------
    pure module function spd_get_simplify_factor(this) result(x)
        class(scatter_plot_data), intent(in) :: this
        real(real64) :: x
        x = this%m_simplifyFactor
    end function
 
! --------------------
    module subroutine spd_set_simplify_factor(this, x)
        class(scatter_plot_data), intent(inout) :: this
        real(real64), intent(in) :: x
        this%m_simplifyFactor = x
    end subroutine
 
! ------------------------------------------------------------------------------
    pure module function spd_get_data_dependent_colors(this) result(rst)
        class(scatter_plot_data), intent(in) :: this
        logical :: rst
        rst = this%m_dataDependentColors
    end function
 
! --------------------
    module subroutine spd_set_data_dependent_colors(this, x)
        class(scatter_plot_data), intent(inout) :: this
        logical, intent(in) :: x
        this%m_dataDependentColors = x
    end subroutine
 
! ******************************************************************************
! ADDED: JUNE 28, 2021 - JAC
! ------------------------------------------------------------------------------
    pure module function spd_get_filled(this) result(rst)
        class(scatter_plot_data), intent(in) :: this
        logical :: rst
        rst = this%m_filledCurve
    end function
 
! --------------------
    module subroutine spd_set_filled(this, x)
        class(scatter_plot_data), intent(inout) :: this
        logical, intent(in) :: x
        this%m_filledCurve = x
    end subroutine
 
! ******************************************************************************
! ADDED: JAN 12, 2024 - JAC
! ------------------------------------------------------------------------------
    pure module function spd_get_use_var_point_size(this) result(rst)
        class(scatter_plot_data), intent(in) :: this
        logical :: rst
        rst = this%m_useVariableSizePoints
    end function
 
! --------------------
    module subroutine spd_set_use_var_point_size(this, x)
        class(scatter_plot_data), intent(inout) :: this
        logical, intent(in) :: x
        this%m_useVariableSizePoints = x
    end subroutine
 
! ------------------------------------------------------------------------------
end submodule